***Alan Standard Library v2.0***

***User’s Manual***

****

**Feb 13, 2016**

***USER’S MANUAL FOR ALAN STANDARD LIBRARY v2.0***

*Contents*

Introduction *1*

What is different in v2.0? *3*

Locations *25*

Room *26*

Site *26*

Dark locations and the ‘lit’ attribute *27*

The ‘visited’ and ‘described’ attributes *29*

Nested locations *30*

Actors *31*

Pre-defined actor classes in the library *31*

Pre-defined actor attributes in the library *31*

The hero *35*

Describing NPCs *36*

Objects *36*

Object classes defined in the library *36*

The ‘my\_game’ instance and its attributes 5

1) Attributes for the start section 6

2) Attributes for the hero *7*

3) Attributes for locations *7*

4) Illegal parameter messages *7*

5) Default verb check messages *11*

a) attribute checks *12*

b) location and containment checks for actors and objects *17*

c) checking location states *21*

d) logical checks  *21*

e) additional checks for classes *23*

6) Implicit taking message *24*

Have the game banner show at the start *47*

The philosophy used in deciding successful and unsuccessful outcomes for action in the library verbs *48*

Runtime messages *48*

Verb syntaxes used in the standard library  *51*

Default attributes used in the standard library  *55*

Translating to other languages *56*

Reference guide *57*

Short examples *6*

**INTRODUCTION**

This is the manual for the ALAN Standard Library v2.0. This manual describes how to use the library together with the ALAN Interactive Fiction Language system v3.0 and subsequent versions, to create works of interactive fiction, or text adventures. The library defines responses for verbs and commands commonly used in gameplay, such as *examine*, *take*, *drop* and *attack*, together with numerous other ones. The library also defines various global attributes as well as object and actor attributes and classes, together with illegal parameter messages.

The first official version (v1.0) of the ALAN Standard Library was published in 2010. Before that, versions 0.x, written by Steve Griffiths, were available for use. The writer of the current version is Anssi Räisänen.

The ALAN Standard Library v2.0 consists of the following five primary library files:

lib\_classes.i

lib\_definitions.i

lib\_locations.i

lib\_messages.i

lib\_verbs.i

In addition, the following files, none of which are necessary for using the library, can be found in the library distribution package:

changelog.txt A text file listing the changes made to the library after version v2.0 (= none so far)

copying.txt A text file clarifying some copyright issues

library.i A file that imports all library files. Just use the line IMPORT ‘library.i.’.

to import the standard library to your game

mygame\_import.i An auxiliary, not obligatory, definition file for the library. If you need to edit a great

number of default library messages (for verb outcomes etc.), you can edit this

file and import it to your game project

newgame.a3c A compiled game of the source code included in ‘newgame.alan’ (below)

newgame.alan A barebones game source file defining some necessary coding when starting to write

a new game. You can use this as a starting point for a new project

newgame.ifid An IFID identification number of the compiled ‘newgame.a3c’ file

quickref.text A quick summary of the library features and how to use them

quickstart.pdf A quick summary for starting to use the library.

testgame.a3c The compiled test game, ready to run and play, to test the features of the library

testgame.alan The source code for a test game showcasing the features of the library

testgame.ifid An IFID identification number of the compiled ‘testgame.a3c’ file

Thank you to Steve Griffiths for the score notification code snippet and for the early versions of the library, and to Alan Bampton for the code used for clothing objects (layered clothing).

And naturally many thanks to Thomas Nilsson for the ALAN Interactive Fiction Language.

**What is different in v2.0?**

- the author doesn’t necessarily need to access the library files any longer when writing a game. It is possible to write a game just importing the library files and define everything in your own game source file(s). It is still possible of course to edit the library directly if this is preferred. There are also some cases when the library needs to be accessed, e.g. when changing standard runtime messages.

- there are five library files in v2.0 instead of the four in v1.0: ‘lib\_classes.i,’ ‘lib\_definitions.i’ ‘lib\_locations.i’, ‘lib\_messages.i’ and ‘lib\_verbs.i’.

- the hero instance is left out of the library. It can be now defined from scratch by the game author. (There are still checks for the hero within various verbs, and these work whether the author defines the hero instance or not. There are also numerous default verb responses and other messages that take the hero into account, just like in the previous version of the library, but these can be easily overridden.)

- an obligatory meta instance, *my\_game*, needs to be coded by the author to each new game:

THE my\_game ISA DEFINITION\_BLOCK

END THE.

Without it, the game won’t compile correctly. Inside this instance, it is possible for example to override messages

provided by the library:

THE my\_game ISA DEFINITION\_BLOCK

VERB examine

DOES ONLY “Nothing special.”

END VERB.

END THE.

and so on.

- check messages and illegal parameter messages can be edited much more smoothly. You don’t have to e.g. edit the same check for every verb separately (or cut and paste); you can now change the wording in one place and it will affect all the places where that same check is found, throughout the library.

- the ‘listable\_container’ class of version 1.0 has been renamed ‘listed\_container’ which sounds slightly better.

- there are some new attributes:

*- ‘allowed’* is needed for container objects to indicate which objects they can take:

THE drawer ISA LISTED\_CONTAINER IN nightstand

HAS allowed {diary, keys}.

…

END THE drawer.

This will effectively prohibit unwanted successful outcomes for player commands such as >put coffee cup in drawer or >put suitcase in drawer. Besides *put\_in*, this attribute also applies to the verbs *empty\_in*, *pour\_in* and *throw\_in*.

- *‘distant/not distant’*, in addition to the existing ‘*reachable/NOT reachable*‘. This has proved to be a handy distinction to have at hand. It is possible for the hero for example to talk with an NPC (non-player character) that is not reachable (e.g. if the hero is lying down on a bed, or tied up to a chair), but not with one that is distant. Similarly, you can throw something at, to or into a not reachable instance (for example a basketball into a basket), but not at, to or into a distant one. There are also some other individual cases where you can manipulate not reachable objects as opposed to distant ones. The default responses for not reachable and distant objects are a bit different: a not reachable object is described to be “out of your reach” but a distant object is “too far away”. For example the library-defined ceiling object for indoor rooms is not reachable (“The ceiling is out of your reach”) while the library-defined sky object is distant (“The sky is too far away”).

- actors are defined to be either *compliant* or *NOT compliant*. By default, they are NOT compliant. This attribute is needed when we try to get something from an NPC. For example, the verb *take\_from* doesn’t work with actors by default; the only way to make an actor give you something in their possession by default is to *ask for* it. Also implicit taking doesn’t work with actors, i.e. if an NPC is carrying an apple and you type >eat apple, the outcome will be “That seems to belong to the [NPC].”; the apple won’t be automatically taken by the hero like it would if it was not carried by anyone.

- every door has an ‘*otherside’* attribute which can be used if the game author wants to ensure that a door will be correctly opened, closed, locked and unlocked from both sides. When the open/closed status of a door instance changes, the status of its *otherside* counterpart (in the next room) is changed accordingly by the library. (If the author declares no *otherside* attribute for a door, then this doesn’t happen automatically.)

THE kitchen\_door ISA DOOR AT kitchen

HAS otherside livingroom\_door.

IS lockable. IS locked.

HAS matching\_key small\_key.

END THE.

THE livingroom\_door ISA DOOR AT livingroom

END THE.

THE small\_key ISA OBJECT IN drawer

END THE.

Above, the livingroom\_door will also be lockable, locked, have *otherside* kitchen\_door and can be opened by the small\_key, even if none of these attributes were explicitly declared in the livingroom\_door code.

- every lockable door has a *‘matching\_key’* attribute which should be declared at the door instance if it’s meant to be locked/unlocked. If the hero carries the matching key of a locked door, unlocking will be possible through just “unlock door”or even “open door” and not necessarily using the longer formulation “unlock door with key”. This attribute also eases up the coding required for locked doors.

- the ‘closed’ and ‘closeable’ attributes have been changed to ‘*open*’ and ‘*openable*’ which is more intuitive.

- the SCENERY class has been removed. Instead, ‘*scenery*’ is declared as an attribute.

- similarly, the BACKGROUND class has been removed. Use the (NOT) reachable/distant attributes instead where applicable.

- some object classes are made to work in a simpler way from v1.0. For example, an object in the subclass ‘liquid’ won’t have to be declared to have a ‘vessel’ attribute any longer (if the liquid is carried in a vessel of any kind). Similarly, clothing objects worn by NPCs can now be implemented more smoothly.

- formatting the game title, author, year and version at the start of the game is made easier. There is an automatic formulation which can be easily included if desired.

- some default verb responses have been changed from v1.0. For example, the response for *ask\_about* has been simplified.

**Locations**

*Location classes pre-defined in the library:*

*ROOM  
SITE   
DARK\_LOCATION*

*Location attributes pre-defined in the library:*

*IS lit.*

*IS visited 0.*

*IS described 0.*

Using the standard library, basic locations are implemented just like advised in the ALAN Manual, for example:

THE bedroom ISA LOCATION

DESCRIPTION "This is your bedroom."

EXIT north TO bathroom.

EXIT east TO closet

CHECK "The closet is locked."

END EXIT.

END THE.

THE bathroom ISA LOCATION

DESCRIPTION "This is the bathroom."

EXIT south TO bedroom.

END THE.

etc.

*More on the pre-defined location classes:*

ROOM

If you want to implement an indoor location, you can declare it ISA ROOM:

THE kitchen ISA ROOM

DESCRIPTION “…”

…

END THE kitchen.

All ROOMs will automatically have walls, a floor and a ceiling.

SITE

If you want to implement an outdoor location, you can declare it ISA SITE:

THE meadow ISA SITE  
 DESCRIPTION “…”

…

END THE meadow.

All SITEs will automatically have a ground and a sky.

NOTE: it is often a good idea to modify the 'examine' verb for the wall, ceiling, floor, ground and sky objects to add more immersion to the game. Here is an example for 'wall':

THE my\_game ISA DEFINITION\_BLOCK -- see p.\_\_

...

VERB examine

CHECK obj <> wall

ELSE

IF hero AT kitchen

THEN "The walls are lined with shelves."

ELSIF hero AT livingroom

THEN "The wallpaper has a nice flower pattern."

ELSIF...

END IF.

...

END VERB.

END THE my\_game.

DARK\_LOCATION and the ‘lit’ attribute

In dark locations, actions requiring seeing are automatically disabled by the library. All dark locations have the attribute ‘NOT lit’. They need a lit lightsource object to be present to be lit. To implement a dark location, it is enough to implement it for example in the following way:

THE basement ISA DARK\_LOCATION

EXIT up TO hall.

END THE.

The description of a dark location will be by default "It is pitch black. You can't see anything at all."

This default can be changed by editing the *dark\_loc\_desc* attribute of the *my\_game* instance (see p.\_\_).

If you add a description of your own to a dark location, this description will be shown only if the location is lit up by any means:

THE basement ISA DARK\_LOCATION

DESCRIPTION "Only useless junk can be seen lying around."

EXIT up TO hall.

END THE.

In order that a *dark\_location* is lighted, a *lightsource* object (a lantern, a match, a ceiling lamp, any other kind of light object) should be present.

In darkness, you are not able to manipulate things other than turn on a *lightsource* and drop items you're carrying (these checks are found in 'lib\_verbs.i'). You can exit normally and use verbs that don't require seeing, such as 'smell', 'listen' and 'think'. If you are in a dark location with an NPC (= a non-player character), you are able to communicate with them by asking and telling, but not by showing and giving. If you wish to change these restrictions, see the respective verbs in 'lib\_verbs.i' and modify their checks.

Note that you cannot change the name of a location mid-game. Thus, if you define a dark location called e.g. 'Darkness' and wish to make it lit at some point in the game, the name will still be ‘Darkness' even if the location description can be changed to describe the illuminated location. To show a change in the location name, you must locate the hero in another location when the dark location is lit. For example,

THE lantern ISA LIGHTSOURCE

VERB turn\_on

DOES

IF hero AT mysterious\_dark\_room

THEN LOCATE hero AT treasure\_chamber.

...

END IF.

...

END VERB.

END THE.

etc.

Alternatively, you can also use a rule, e.g.

WHEN lantern IS lit

AND hero AT mysterious\_dar\_room

THEN LOCATE hero AT treasure\_chamber.

Note that you won’t always need to define a dark location to be a member of the subclass *dark\_location*. This applies in cases when you don’t wish to implement lightsources to make locations lit or not lit. (*All* location instances have by default the attribute ‘lit’ and they can be made ‘NOT lit’ when needed.) For example, suppose you want all dark locations in the game to become lighted simultaneously. It can be done e.g. like this:

THE main\_power\_switch ISA DEVICE AT lobby

VERB switch\_on

DOES ONLY

FOR EACH d1 ISA LOCATION, IS NOT lit

DO

MAKE d1 lit.

END EACH.

END VERB.

END THE.

If we had used the *dark\_location* class above, all locations to be lighted should have had a lightsource object present in them, and all these lightsource objects would have needed to be changed to ‘lit’, which would have meant extra programming.

Even normal locations, when not lit, will have the description “It is pitch black. You can’t see anything at all.”, so you can use the above method with no worries. The only reason for a specific *dark\_location* subclass to exist is to make it automatic for them to be lit or not lit when the hero is carrying around and/or turning on and off lightsources so that the game author won’t constantly need to remember to change the attribute of the location to ‘lit’ or ‘NOT lit’ in all imaginable cases.

Also consider the following case: suppose the hero can make a basement (a location belonging to the class *dark\_location*) lighted by turning on a light switch that is at the top of the stairs leading to the basement (a different location from the basement itself). We program the light switch object so that when the hero turns it on, the basement will be ‘lit’. All ok so far. However, when the hero enters the actual basement, it will be dark. Why? Because there is no *lightsource* present in the basement; we just changed the attribute of the basement location to ‘lit’, but this is not enough. A check at entering any *dark\_location* will make the location dark if no lit *lightsource* is present. You should program a lamp, a *lightsource* object, to be present in the basement, and this lamp should be made ‘lit’ at the same time when the hero turns on the switch at the top of the stairs. But again, this is more than is necessary to reach the wanted effect. Here, like above, you could just make the basement a normal location (and “NOT lit” to start with), and just change the attribute to ‘lit’ when the hero turns on the light switch.

*The ‘visited’ and ‘described’ attributes*

IS visited 0.

A location not visited at all has the 'visited' value 0. When the hero enters it the first time, the 'visited' value will change to 1. On the second visit the value will be 2, etc.

Now, in your source code you can define something like the following:

THE kitchen ISA LOCATION

DESCRIPTION

"You are in the kitchen."

IF visited OF THIS = 1

THEN "This is your first time here."

ELSE "You remember you've been here before."

END IF.

...

END THE.

Note that if you have an NPC moving around in the game, the visited value of any location will increase when the NPC enters the location, as well (ENTERED applies to all moving actors). This is most often not what is wanted, and that's why an 'if' statement (IF CURRENT ACTOR = hero) is included in the ENTERED section for all locations, in the library.

You can also check whether the hero has been in a location if needed:

THE king ISA ACTOR

...

VERB ask

WHEN act

IF topic = treasure\_chamber

THEN

IF visited OF treasure\_chamber = 0

THEN "You are not supposed to know anything

about the treasure chamber – you

haven't found it yet."

ELSE """Just take what you want from the

chamber"", the king smiles."

END IF.

...

END IF.

END VERB.

END THE.

IS described 0.

Suppose you want the location description to be different after the first time the description is shown, even if you are in the location still for the first time. Then, you can use the 'described' attribute. A location not described at all has the ‘described’ value 0. When the player reads the location description for the first time, the value is 1, the next time the value will be 2, etc :

THE library ISA ROOM

DESCRIPTION

IF described OF THIS = 1

THEN "There is an old man reading at a table in one of the

corners."

ELSE "The old man keeps on reading at his table."

END IF.

END THE.

or:

THE meadow ISA SITE

DESCRIPTION

"Flies and other insects buzz around you"

IF described OF meadow > 5

THEN ", which starts to annoy you little by little"

END IF.

"."

END THE.

*Nested locations*

Nesting locations is straightforward, as described in the ALAN Manual:

THE house ISA LOCATION

END THE house.

THE kitchen ISA LOCATION AT house

END THE kitchen.

THE bedroom ISA LOCATION AT house

END THE bedroom.

THE livingroom ISA LOCATION AT house

END THE livingroom.

Note: for sites and rooms ( = outdoor and indoor locations, respectively) to work correctly when nested, the mother location should be of the same kind as the nested locations. For example, in the example above, if you declare the kitchen, the bedroom and the living-room to be ROOMS, the house instance should also be declared a ROOM. Sometimes this can bring problems: say you have a driveway location, with a nested location where you are inside your car. The driveway would naturally be a SITE (outdoor location), while the inside of your car is more naturally a ROOM. The best way to solve this is to make both of these locations just LOCATIONs and implement your own floor, walls and ceiling objects for the inside of the car, and your own ground and sky objects for the driveway.

**Actors**

*Pre-defined actor classes in the library:*

*PERSON  
MALE  
FEMALE*

There are two points where a *person* differs from an ordinary *actor*. Firstly, a person has the ability to talk, i.e. the verbs *ask, ask\_for, say\_to, talk\_to* and *tell* work with persons only. Secondly, actors and persons are described differently when their inventory is empty. Persons are described as for example “The man is empty-handed.” while other actors (than persons) are described as for example “The dog is not carrying anything.”

*Male* and *female* are subclasses of *person*, so they have the ability to talk. If you need to implement a male or female animal, do like this:

THE dog ISA MALE

CAN NOT talk.

END THE dog.

*Pre-defined actor attributes in the library*

*IS NOT inanimate.*

*IS NOT following.*

*IS NOT sitting.*

*IS NOT lying\_down.*

*IS NOT named.*

*IS wearing {null\_clothing}.*

*IS NOT compliant.*

IS NOT inanimate.

Verbs *push, push\_with, rub, scratch, search, touch and touch\_with* won’t have successful outcomes with animate objects (= actors). To ensure this, the *(NOT) inanimate* attribute is used.

IS NOT following.

By default, NPCs won’t follow the hero around the game map.

To make an actor follow the hero, give it the 'following' attribute, e.g.:

THE bob ISA ACTOR

...

VERB whatever

DOES MAKE bob following.

END VERB.

....

END THE bob.

If you wish to have an actor follow the hero right from the start of the game, you can naturally just declare

THE servant ISA ACTOR

IS following.

...

END THE.

To stop an actor from following the hero, just make the actor NOT following.

IS NOT sitting.

IS NOT lying\_down.

These two attributes exist to allow the author to make the hero, or another actor, sitting or lying down. The outcomes for the commands >sit and >lie down are not successful by default, however, and must be manually implemented by the author:

THE my\_game ISA DEFINITION\_BLOCK

VERB sit

DOES ONLY “You sit down on the floor.”

MAKE hero sitting.

END VERB.

VERB lie\_down

DOES ONLY “You lie down on the floor.”

MAKE hero lying\_down.

END VERB.

END THE.

Similarly, it is possible for the player to command that the hero (or an NPC) sit or lie down on a supporter object (>lie on bed, >sit on chair), but the action is not successful by default, and must be manually implemented by the author. Refer to: Objects => Supporters.

IS NOT named.

If you don't need an article in front of an actor name (e.g. 'Jim', as opposed to e.g. 'a/the man'), declare the instance as 'named':

THE jim ISA ACTOR AT room1

IS named.

...

END THE.

If you have in your game an actor that starts off as unnamed (such as 'a man'), and the player learns his name later on (say, 'Jim'), you should define the actor in for example the following way to make the player able to refer to him with both 'man' and 'Jim':

THE jim ISA PERSON AT room1

NAME man

NAME Jim

PRONOUN him

MENTIONED

IF jim IS NOT named

THEN "man"

ELSE "Jim"

END IF.

VERB ask

WHEN act

IF topic = name

THEN """My name is Jim"", he replies."

MAKE jim named.

END IF.

END VERB.

END THE.

IS wearing null\_clothing.

By default, the hero character, or any other actor for that matter, isn’t described as wearing any particular clothing, If the author implements some clothing for the hero, this will show up by default in the hero’s description after *examine* (‘x me’).

To implement clothing worn by the hero, locate all such clothing items in the container *worn*:

THE hat ISA CLOTHING IN worn

IS headcover 2.

DESCRIPTION “”

END THE.

Refer also to: Objects => Clothing.

IS NOT compliant.

An actor only gives something to the hero if it is in a compliant mood. In practice, this happens by default only when the hero asks the actor for anything. For example, *take\_from* is not successful by default with actors.

Implicit taking of objects is not successful, either, if the object happens to be held by an NPC who is not compliant, and the following happens:

>eat apple

That seems to belong to Mr Smith.

But if we declare:

THE mr\_smith ISA ACTOR AT room1

NAME mr smith

IS compliant.

…

END THE.

then, the outcome for implicit taking would be successful:

>eat apple

(taking the apple first)

You eat all of the apple.

To disable even the verb *ask\_for*, so that the NPC won’t give you something even if you ask for it, use DOES ONLY at the actor instance:

THE bob ISA ACTOR AT room1

…

VERB ask\_for

WHEN act

DOES ONLY “He doesn’t seem to be cooperative.”

END VERB.

END THE.

*The hero*

The hero instance is left out of the library altogether. If you need to add attributes or verb responses to the hero, define it from the scratch in your own game source, for example:

THE hero ISA ACTOR

HAS strength 20.

IS NOT hungry.

VERB examine

DOES ONLY “You’re John Smith, proud of your unusual name.”

END VERB.

END THE hero.

*Describing NPCs*

When the player types ‘examine [actor]’, the response will be the default “You notice nothing unusual about [the actor].” If you wish to have the actor’s possessions and worn clothing listed after *examine*, you should add “LIST [actor].” manually to the appropriate verb (typically *examine*) of each actor instance:

THE boy ISA PERSON

IS wearing {hat}.

VERB examine

DOES ONLY “A boy about twelve years old.” **LIST boy.**

END VERB.

END THE boy.

THE coin ISA OBJECT IN boy

END THE.

THE hat ISA CLOTHING IN boy

END THE.

will result in:

>examine boy

A boy about twelve years old. The boy is carrying a coin and a hat (being worn).

**Objects**

*Object classes predefined in the library*

*CLOTHING  
DEVICE  
DOOR*

*LIQUID  
LISTED\_CONTAINER  
SOUND  
SUPPORTER*

*WEAPON  
WINDOW*

Note: the background and scenery classes introduced in v1.0 have been removed. For backgrounds, use the ‘distant’ or ‘not reachable’ attributes. For scenery objects, use the attribute ‘IS scenery’.

CLOTHING is a piece of clothing the hero or an NPC wears. Clothes are prevented from being worn in an illogical order, for example you cannot put on a shirt if you are already wearing a jacket, and so forth.

Thanks to Alan Bampton from whose ‘xwear’ extension the code for this class has been adopted.

(The following paragraphs are taken from Alan Bampton's original 'xwear' documentation, with minor alterations.)

The basic idea is that clothing is worn in 'layers' and it is rather silly to allow players to, say, take off or put on a shirt if they are wearing a jacket. To simulate this in ALAN there is a numeric based layering system, and the body is divided into five zones of coverage. The zones are 'head', 'hands', 'feet', 'top' (for top half of torso) and 'bot' (for bottom half of torso). All objects have these five zones defined as default attributes (set to 0), for the head zone the attribute is headcover for the hands zone handscover and so on. Every clothing object will thus need one or more of its 'zonecover' attributes set to reflect the zone(s) it covers and its relative position in the layers of clothing worn. A simple example would be a shirt, this covers only the 'top' zone and so needs its topcover attribute to be set (to 8, just why it's 8 will become clear shortly).

The principle used is that the closer to the skin an item is normally worn, the lower its 'cover' attribute is. The library operates on the assumption that items with higher value cover attributes for a particular zone are worn over items with lower value attributes. When a player attempts to put on an article of clothing, each zone it would affect is checked and compared to the related zonal total of any clothes already worn. If the value of the new clothing is not greater that the total(s) of clothing already worn (on a zone by zone basis) then the library will not allow the wearing of that item. There are a few notable exceptions to this rule, but those will be dealt with a little later.

How it works in practice

-------------------------------

This part of the library might sound complex, but it is actually very simple to use, here's an example: assume our hero starts the game wearing just a vest and shorts and the player issues the command 'put on shirt'. A quick check of the chart below should reveal that a shirt has only its topcover attribute set to non-zero, (all the other zones are zero, which means they are irrelevant for this item). The library totals the topcover attributes of all the clothes currently worn, like so: Starting with a total of 0, and checking the vest, this has a topcover attribute of 2, so total topcover is 0 + 2 = 2. Next the library checks the shorts, these have a topcover attribute of 0, so total topcover is 2 + 0 = 2. As there are no other clothes to consider, the library now compares the topcover attribute of the item we are attempting to put on, (a shirt with a topcover attribute of 8 in this case) to the total value of items already worn (2). Because the topcover attribute of the shirt (8) is greater than the calculated total (2), this is evaluated as being a 'legal' instruction and the library allows the shirt to be put on. Now consider the situation had the player started the game wearing vest, shorts and a jacket, this is what happens should he try to 'put on the shirt.' Starting with a total of 0, and checking the vest, this has a topcover attribute of 2, so total topcover is 0 + 2 = 2. Next the library checks the shorts, these have a topcover attribute of 0, so total topcover is 2 + 0 = 2. Finally the library checks the jacket, this has a topcover attribute of 32, so total topcover is 2 + 32 = 34. Because the topcover attribute of the shirt (8) is now not greater than the calculated total (34), this is evaluated as being an 'illegal' instruction and the library won't allow the shirt to be put on.

That demonstrates the basic principle of the library, removing clothes uses a variation of the 'compare to total' equation to allow / disallow removal of clothing, an example would be that our vest, shorts and jacket wearing player would NOT be allowed to remove the vest while he still had the jacket on.

Exceptions to the rule...

------------------------------

The numbers in the chart are not born of some sort of weird fixation with multiples, there is a very good reason why the numbers are set as they are, computer/math types will recognize the sequence and realize it is all 'binary' based and know it makes it possible to calculate exactly what the player is wearing in terms of layers.

Some female clothing breaks the rules defined above and is not so easy to deal with. An example: although pantyhose is worn under a skirt, dress or coat it can actually be put on or removed with the garment worn over it still on. The library recognizes this capability and deals with it properly by assigning the dress/skirt and coat items particular properties in that they don't affect the ability to wear or remove lower layer clothing that covers the bottom of the torso only. Although it's physically possible to put on/remove trousers while wearing a skirt or dress, this (and a few other neat dressing/undressing tricks) is considered illegal here.

How to create pieces of CLOTHING

-----------------------------------------------

Here is a quick overview for using the class 'clothing'.

A piece of clothing in your game code should look something similar to the following four examples:

THE jacket ISA CLOTHING AT lobby

IS topcover 32.

END THE.

Use IN to refer to containers:

THE jeans ISA CLOTHING IN wardrobe

IS botcover 16.

END THE.

IN worn = worn by the player character (hero):

THE hat ISA CLOTHING IN worn

IS headcover 2.

END THE.

Worn by an NPC called Joe:

THE sweater ISA CLOTHING IN joe

IS NOT takeable.

-- Don't declare numeral clothing attributes for NPCs (unless the hero

-- is meant to take and wear the NPC's clothing).

-- NPCs cannot wear clothing in layers!

END THE.

THE joe ISA ACTOR AT room1

IS wearing {sweater}.

END THE joe.

Note above that you must list the clothing worn by an NPC in a set named ‘IS wearing’, at the NPC instance. If you don’t do this, the NPC will be described as just carrying the piece of clothing in his hands.

Note that if the piece of clothing worn by an NPC is not meant to be takeable by the player character, you should declare the piece of clothing to be ‘NOT takeable’.

In defining a piece of clothing, you should

1) define it ISA CLOTHING (and not ISA OBJECT)

2) give it one of five attributes 'headcover', 'topcover', botcover', 'footcover' or 'handcover'; sometimes two of these are needed. Which attribute(s) to use depends on the type of clothing; see the clothing table below.

3) A number 2, 4, 8, 16, 32 or 64 needs to be added after the above attribute. You cannot decide the number yourself; look it up from the clothing table below. If the value of an attribute for a piece of clothing is 0 in the table, don't mention this attribute in connection with your clothing object.

-- The above is enough; the rest is then handled automatically by the library.

The clothing table

Here is the chart showing a selection of fairly typical clothing items and the values to set to obtain appropriate behaviour. Should you wish to create an article of clothing not listed, usually a bit of lateral thought as to what it is most like and where it fits into the scheme of things will suggest a workable set of values, but be aware that you MUST use values in this chart, simply adding things with intermediate values is probably going to create nasty bugs:

Clothing Headcover Topcover Botcover Foot- Handcover

cover

hat 2 0 0 0 0

vest/bra 0 2 0 0 0

undies/panties 0 0 2 0 0

teddy 0 4 4 0 0

blouse/shirt/T-shirt 0 8 0 0 0

dress/coveralls 0 8 32 0 0

skirt 0 0 32 0 0

trousers/shorts 0 0 16 0 0

sweater/pullover 0 16 0 0 0

jacket 0 32 0 0 0

coat 0 64 64 0 0

socks/stockings 0 0 0 2 0

tights/pantiehose 0 0 8 2 0

shoes/boots 0 0 0 4 0

gloves 0 0 0 0 2

The library, as it stands, also prevents wearing of duplicate clothes, or things that are logically mutually exclusive - e.g. the player can wear a dress or a skirt, but not both.

DEVICE is a machine or an electronic device, for example a TV. It can be turned (=switched) on and off if it is not broken. Default attributes: 'NOT 'on', NOT broken. A device is by default described as being either on or off when examined.

For example:

THE thingummyjig ISA DEVICE AT lab

END THE.

DOOR can be opened, closed, locked and unlocked. It is by default closed (= ‘NOT open’) and NOT locked. Attributes: openable, NOT open, NOT lockable, NOT locked, HAS otherside door. A door is described by default as being either open or closed when examined.

*Locked doors and keys*

To unlock a locked door, it has to have a *matching \_key* object attributed to it. Only this object can unlock the door.

THE wooden\_door ISA DOOR AT cellar

NAME wooden door

IS lockable. IS locked.

HAS matching\_key iron\_key.

END THE locked\_door.

THE iron\_key ISA OBJECT IN drawer  
END THE.

By default, it will possible to unlock the door both with >*unlock door* and >*open door* (if the player character is carrying the correct key at the time) as well as with the longer formulations >*unlock door with key* and >*open door with key*.

However, it is not possible to make this automatic by using compass directions only. For example, if the door was to the east of the hero, the command >*e* cannot recognize on the library level whether the hero is carrying the key or not. The author must implement this manually.

Every door between two rooms needs an *otherside* attribute in order for the other side of the door to behave correctly when the door is opened, closed, unlocked and locked.

The *otherside* of a door need not have its other side defined any longer, as the library makes the deduction that if a door has an *otherside*, this other side will have the original door as its *otherside* in turn. Also, the lockable/locked/not locked/openable/open/not open attributes of a door instance will be automatically assumed to be the same for its *otherside* counterpart at the start of a game. The same applies also to the *matching\_key* attribute. That’s why it is much shorter to implement the otherside of a door:

THE wooden\_door1 ISA DOOR AT room1

NAME wooden door

IS lockable. IS locked.

HAS matching\_key iron\_key.

HAS otherside wooden\_door2.

END THE locked\_door.

THE wooden\_door2 ISA DOOR AT room2

NAME wooden door

END THE.

Above, the wooden\_door2 is also lockable and locked at the start of the game, has *wooden\_door1* as its otherside and can be opened with *iron\_key*. (It wouldn’t hurt even if you did declare all of these attributes under *wooden\_door2*, to be sure, but it is not necessary.)

See also: chapter *Short examples*, example 5.

LIQUID can only be taken if it is in a container. You can fill something with it, and you can pour it somewhere. A liquid is by default NOT drinkable.

If you have some liquid in a container in your game, you should declare the liquid instance this way:

THE juice ISA LIQUID

IN bottle

END THE juice.

Then, taking and pouring liquids work smoothly.

The verb 'pour', as defined in this library, also works for the container of a liquid; i.e. if there is some juice in a bottle, 'pour bottle' and 'pour juice' will work equally well. Note, however, that the verb 'empty' is not a synonym for 'pour'; 'empty' only works for container objects. Consequently, >empty bottle will work but >empty juice wont.

LIGHTSOURCE is natural or NOT natural (a natural lightsource is for example a match or a torch). It can be turned on and off, lighted and extinguished (= put out) if it is not broken. A natural lightsource cannot be turned on or off, it can only be lighted and extinguished (= put out). When examined, a lightsource is by default supplied with a description of whether it is providing light or not. The default attributes for a lightsource object are: natural, NOT lit.

THE torch ISA LIGHTSOURCE AT cave

IS lit.

END THE.

THE lamp ISA LIGHTSOURCE AT bedroom

IS NOT natural.

END THE.

LISTED\_CONTAINER is an object which has the container property. The contents of a *listed\_container* will be listed both after 'look' (= in the room description), 'look in' and 'examine', if it is open. (The contents of a normal container object are not automatically listed after 'examine' but only after 'look' (=room description) and 'look in').

To implement a *listed\_container* do for example like this:

THE box ISA LISTED\_CONTAINER AT room1

...

END THE.

The contents of a *listed\_container* are also listed when it is opened. This doesn't happen with normal containers.

For the command 'inventory' to list the contents of a container object the hero is carrying, redefine the verb 'inventory' under the *my\_game* instance in your source file for example this way:

VERB inventory

DOES

IF bag IN hero

THEN LIST bag.

END IF.

IF box IN hero

THEN LIST box.

END IF.

...

END VERB.

If you don’t’ do this, the bag and the box will be listed after the command 'inventory' in the following way:

"You are carrying a bag and a box."

only. But with the above addition, the outcome is e.g.

"You are carrying a bag and a box. The bag contains a loaf of bread. The box

is empty."

To declare a *listed\_container* the contents of which should not be listed after 'look' or 'examine', declare it an 'opaque container' in the following way:

THE box ISA LISTED\_CONTAINER

OPAQUE CONTAINER

...

END THE.

Objects in an opaque container cannot be seen or manipulated. To change this, declare e.g.

MAKE box NOT OPAQUE.

(This is handled automatically by the library when a container is opened or closed.)

*Putting things in containers*

It is only possible to put something into a container if this something is included in the ‘*allowed*’ set of the container object.

THE drawer ISA LISTED\_CONTAINER IN nightstand

HAS allowed {diary, keys}.

…

END THE drawer.

In the example above, it wouldn’t be possible to put anything else in the drawer, for example a chair or a suitcase. The response would be e.g. “The chair doesn’t belong in the drawer.”, etc.

This applies not only to the verb *put\_in* but also to *empty\_in*, *pour\_in* and *throw\_in.*

Everything programmed to be in a container by the author at the start of the game will be automatically included in the ‘allowed’ set of the container. Thus, for example if the author implements an apple in a bowl and the hero character takes it, it will be possible for the hero to put the apple back into the bowl, without the author having to implement any separate ‘allowed’ attributes for this to happen. But note if you have for example a ticket dispenser in your game and the hero takes a ticket from it, it would be possible to put the ticket back into the dispenser, the way things work by default. This is not what is wanted in this case. That’s why in that case you should do either:

THE ticket\_dispenser ISA LISTED\_CONTAINER AT lobby

…

VERB put\_in

WHEN cont

DOES “That’s not possible.”

END VERB.

END THE.

or, alternatively:

THE ticket ISA OBJECT IN ticket\_dispenser

INITIALIZE

EXCLUDE THIS FROM allowed OF ticket\_dispenser.

END THE ticket.

SOUND can be listened to but not examined, searched, smelled or manipulated. It cannot initially be turned on or off, this has to be implemented manually by giving the sound the 'switchable' attribute.

SUPPORTER You can put things on a supporter and you can stand, sit down or lie on it. Standing, sitting or lying down on a supporter is not allowed by default, however, but must be manually implemented by the author:

THE bed ISA SUPPORTER AT bedroom

…

VERB lie\_on

DOES ONLY

“You lie down on the bed.”

MAKE hero lying\_down.

END VERB.

END THE.

Remember that it is not possible to locate an actor inside an object, for example in a bed container. Using the sitting or lying\_down attributes should be enough to account for these situations and to create the impression that the hero is located on a supporter object. When the hero is made sitting or lying\_down, certain actions are disabled by the library (e.g. *attack*, *jump* etc.). It is the author’s responsibility to make certain objects in the location NOT reachable as needed, while the hero is lying down or sitting, and also to prohibit movement or at least implement a clarifying message of the hero standing up, before going in any direction.

A supporter is declared a container, so that you can take things from it. When there's something on a supporter, a listing of it will appear in the room description and after 'examine', by default.

To place objects on a supporter:

Define the supporter first; e.g.

THE tray ISA SUPPORTER

...

END THE.

Then, implement the objects on the supporter like this:

THE apple ISA OBJECT

IN tray

...

END THE.

Note the IN above, even if the apple will be described as being \*on\* the tray. Similarly, to implement a book to be found on a table (the table being a supporter object) :

THE book ISA OBJECT

IN table

...

END THE.

Note that the 'examine' command will list what is on the surface of a supporter, not what, if anything, is inside the supporter. For example, if you have a supporter called 'table' in your game with two drawers in it,

DON'T do this:

THE drawer1 ISA OBJECT

NAME bottom drawer

CONTAINER

IN table.

END THE.

or this:

THE drawer2 ISA LISTED\_CONTAINER

NAME top drawer

IN table.

END THE.

This would result in something like "There's a table here. On the table you see a book, a bottom drawer and a top drawer."

Instead, do the following:

THE table ISA SUPPORTER

AT bedroom

HAS components {drawer1, drawer2}.

...

VERB examine

DOES

FOR EACH c IN components OF THIS DO

SAY "The table has" SAY AN c. "."

IF c IS open

THEN LIST c.

ELSE SAY THE c. "is closed."

END IF.

END FOR.

END VERB.

...

END THE.

THE drawer1 ISA LISTED\_CONTAINER

OPAQUE CONTAINER

NAME bottom drawer

AT bedroom

IS NOT open.

END THE.

THE drawer2 ISA LISTED\_CONTAINER

NAME top drawer

AT bedroom

IS open.

END THE.

THE book ISA OBJECT IN table

...

END THE book.

THE diary ISA OBJECT IN drawer2

...

END THE diary.

In other words, declare the drawers components of the table, in the manner described above. The result will then be e.g. something like this:

"You see a table here. There is a book on the table. The table has a bottom drawer. The bottom drawer is closed. The table has a top drawer. The top drawer contains a diary."

WEAPON is fireable (e.g. a cannon) or NOT fireable (e.g. a baseball bat), the latter being the default. The verbs *attack\_with* and *kill\_with* won’t have successful outcomes if the second parameter in them is not a weapon. (Even when the second parameter is a weapon, the outcome of the action is not successful by default. You must implement a successful outcome manually at the instance level.)

THE pistol ISA weapon IN room1

IS fireable.

END THE.

WINDOW can be opened, closed, looked through and out of. It will be described as being either open or closed when examined, by default. It is by default NOT open.

THE bedroom\_window ISA WINDOW AT bedroom

NAME bedroom window

IS open.

END THE.

**The ‘my\_game’ instance and its attributes**

*My\_game* is an instance that obligatorily has to be included by the author in the game source. Without it, the game won’t compile successfully. At its shortest, the needed formulation is

THE my\_game ISA DEFINITION\_BLOCK

END THE.

The purpose of this meta-instance is to make it less necessary for the author to access the library files to make changes to common game responses and messages needed in the game. That’s why the instance is named “my\_game” – the author can override library responses and replace them with responses that better suit the particular work in progress. The things that the author can define within this instance are

a) default verb responses

e.g. “There is nothing special about the key.”

b) check responses

e.g. “You don’t have the key.”

c) illegal parameter messages

e.g. “That’s not something you can eat.”

d) the implicit taking message

e.g. “(taking the key first)”

In addition, the author can let the game formulate automatically the game title, subtitle, author, year, and game version at game start. This is done through attributes of the *my\_game* instance.

It is also possible to for the author to implement custom global attributes within this instance:

THE my\_game ISA DEFINITION BLOCK

HAS tasks\_left 10.

HAS treasures\_found 0.

…

END THE my\_game.

A typical *my\_game* instance would look something like this:

THE my\_game ISA DEFINITION BLOCK

HAS title "The House In The Fog".

HAS subtitle "An interactive ghost hunt".

HAS author "Xavier Y. Zamborsky".

HAS year 2015.

HAS version 1.

VERB examine

DOES ONLY “Nothing special.”

END VERB.

VERB eat

CHECK hero IS hungry

ELSE “You’re not hungry.”

END VERB.

HAS check\_obj\_not\_scenery\_sg “That’s just scenery.”.

HAS check\_obj\_not\_scenery\_pl “Those are just scenery.”.

HAS illegal\_parameter\_talk\_sg "You can’t possibly talk to that.".

HAS illegal\_parameter\_talk\_pl "You can’t possibly talk to those.”.

END THE my\_game.

In the following, all the various attributes of the *my\_game* instance are listed.

1) Attributes for the start section

The following five attributes have been declared for the game start:

HAS title "My New Game".

HAS subtitle "".

HAS author "An ALAN Author".

HAS year 0000.

HAS version “1”.

If you set the version value to “0” (zero), the version line won’t be shown at all in the game banner. Note also that the version number is in quotes. This enables any kind of textual input to describe the current version, for example version “beta0.1”, and so on.

If the subtitle line remains an empty quote (“”), like above, it won’t show in the banner.

NOTE: In order for the banner to show up correctly, the line

DESCRIBE banner.

needs to be added after the START AT declaration:

START AT bedroom.

“You knew that this evening would be different from usual when you found the mysterious note pushed under your front door.”

DESCRIBE banner.

See also example (3) at the end of this manual.

2) Attributes for the hero

HAS hero\_worn\_header “You are wearing”

HAS hero\_worn\_else “You are not wearing anything.”

Change these to alter the way the hero is described as far clothing is concerned. If no clothing is defined for the hero in the game, these messages won’t show at any time. By default, these messages show at >*inventory.* If the author wishes to have the clothing of the hero described after >*examine me*, the *examine* verb for the hero should be defined this way:

THE hero ISA ACTOR

…

VERB examine

DOES “Blah blah…”

LIST worn.

END VERB.

END THE hero.

3) Attributes for locations

HAS dark\_loc\_desc “It is pitch black. You can’t see anything at all.”

This is the default location description for dark locations. It is shown every time the hero enters a dark location or types “LOOK” while there. Edit this to change the default description of dark locations. If/when a dark location is lighted, this description won’t be shown any longer.

HAS light\_goes\_off "It is now pitch black.".

This message is shown when a light goes off and the location becomes dark.

4) Illegal parameter messages

In this section, all illegal parameter messages used by the library are listed. If you wish to change any of these, you can declare them again in the *my\_game* instance.

NOTE: If you need to change a great number, or all, of these messages, e.g. if you’re writing in another language or you need to change the person or the tense of these messages to better suit your narrative, it is highly recommended that you edit the file ‘mygame\_import.i’ in the library distribution package, find the list of these messages there, edit them, and import the ‘mygame\_import.i’ file to your game source (together with the library). ‘mygame\_import.i’ is a file that lists all possible attributes of the *my\_game* instance for easy modification. It is included in the library distribution package but is not necessarily needed to run a game. It makes sense to re-declare these messages within the *my\_game* instance in your own source file ONLY if you need to change a small number that you are not satisfied with. Looking through the list of these parameter messages in ‘mygame\_import.i’ will give you a much better overview of them and make it easier to edit them in a uniform way to suit your purposes.

NOTE ALSO that changing illegal parameter messages is usually not the first priority of a game author and in many cases they are left as is, as defined by the library. It is much more common to modify the standard verb outcomes or add checks of your own to existing library checks, for example. If changing illegal parameter messages is not a high priority for you, you might wish to skip directly to the next section.

The illegal parameter messages, as also the verb check messages and implicit taking messages further below, use the $ parameter naming approach.

Key to the parameter symbols used in ALAN:

$v the verb the player used

$1 the first parameter the player used (e.g. the noun after the first verb used), without any articles, e.g.

“key” in the command “examine key”)

$+1 the definite form of the first parameter the player used (e.g. “the key”)

$-1 the negative form of the first parameter the player used (e.g. “no key”) (not used in the library)

$01 the indefinite form of the first parameter the player used (e.g. “a key”)

$2 etc. would be the second parameter the player used, ( e.g. the word “key” in “unlock door with key”)

The general message for when a parameter is not suitable with the verb (e.g. “That’s not something you can attack”):

HAS illegal\_parameter\_sg "That's not something you can $v.".

HAS illegal\_parameter\_pl "Those are not something you can $v.".

The library accounts for singular and plural cases; that’s why many messages have both a singular (sg) and a plural (pl) formulation.

In the following there are variations of the above message when a preposition is required after the verb (e.g. “That’s not something you can ask about.” or “That’s not something you can cut things with.”):

For verbs requiring *about* (the library verbs *ask\_about*, *tell\_about* and *think\_about)*:

HAS illegal\_parameter\_about\_sg "That's not something you can $v about.".

HAS illegal\_parameter\_about\_pl "Those are not something you can $v about.".

There are two ditransitive verbs requiring *at* in the library, *fire\_at* (e.g“fire rifle at bear”) and *throw\_at* (e.g. “throw remote control at TV”)*:*

HAS illegal\_parameter\_at "You can’t $v anything at $2.”

The following is needed for the verb *ask\_for* (e.g. “ask servant for tea”):

HAS illegal\_parameter\_for\_sg "That's not something you can $v for.".

HAS illegal\_parameter\_for\_pl "Those are not something you can $v for.".

The verb *take\_from* needs the following formulations:

HAS illegal\_parameter\_from\_sg "That's not something you can take things from.

HAS illegal\_parameter\_from\_pl "Those are not something you can take things from.".

The verbs *dive\_in*, *jump\_in*, *lie\_in* and *swim\_in* use the following parameter messages:

HAS illegal\_parameter\_in\_sg "That's not something you can $v in.".

HAS illegal\_parameter\_in\_pl "Those are not something you can $v in.".

*Climb\_on*, *jump\_on,* *knock*, *lie\_on*, *sit\_on,* *stand\_on, switch\_on*, *turn\_on*, for their part, use the following messages:

HAS illegal\_parameter\_on\_sg "That's not something you can $v on.".

HAS illegal\_parameter\_on\_pl "Those are not something you can $v on.".

For *get\_off*, *switch\_off* and *turn\_of f*, the following parameter messages are used:

HAS illegal\_parameter\_off\_sg "That's not something you can $v off.".

HAS illegal\_parameter\_off\_pl "Those are not something you can $v off.".

The preposition *to* is needed in the verbs *listen\_to* and *talk\_to*:

HAS illegal\_parameter\_to\_sg "That's not something you can $v to.".

HAS illegal\_parameter\_to\_pl "Those are not something you can $v to.".

A slightly different message is needed for *give*, *show*, *tell*, *tie\_to*, *throw\_to* which are ditransitive verbs with the second parameter preceded by *to*:

HAS illegal\_parameter2\_to\_sg "That's not something you can $v things to.".

HAS illegal\_parameter2\_to\_pl "Those are not something you can $v things to.".

For *with*, we have two separate messages. The verbs *kill\_with*, *shoot\_with* and *play\_with* use the following formulation:

HAS illegal\_parameter\_with\_sg "That's not something you can $v with.".

HAS illegal\_parameter\_with\_pl "Those are not something you can $v with.".

while a somewhat bigger group of verbs - *attack\_with*, *break\_with*, *burn\_with*, *close\_with*, *cut\_with*, *fill\_with*, *lock\_with*, *open*\_*with*, *pry\_with*, *push\_with*, *unlock\_with* - are accompanied with a message one word longer: *things* is added, for no other reason than that it sounds better than if left out, as far as these verbs are concerned:

HAS illegal\_parameter2\_with\_sg "That's not something you can $v things with.".

HAS illegal\_parameter2\_with\_pl "Those are not something you can $v things with.".

The communication verbs *ask*, *ask\_for*, *say\_to, talk\_to* and *tell* use a message of their own:

HAS illegal\_parameter\_talk\_sg "That's not something you can talk to.".

HAS illegal\_parameter\_talk\_pl "Those are not something you can talk to.".

We have a separate individual default parameter message for a handful of verbs.

For *consult*, we have the following:

HAS illegal\_parameter\_consult\_sg "That's not something you can find

information about."

HAS illegal\_parameter\_consult\_pl "Those are not something you can find information about."

You’ll find this message at *examine* :

HAS illegal\_parameter\_examine\_sg "That's not something you can examine.".

HAS illegal\_parameter\_examine\_pl "Those are not something you can examine.".

The reason why *examine* doesn’t use the general default message (scroll above) is that when the player types e.g.‘x 34’ the response would be “That’s not something you can x.” which isn’t such pretty-looking as when the verb is printed in full.

The verbs *look\_out\_of* and *look\_through* use prepositions other verbs don’t, and that’s why they need their own messages:

HAS illegal\_parameter\_look\_out\_sg "That's not something you can look out of.".

HAS illegal\_parameter\_look\_out\_pl "Those are not something you can look out of.".

HAS illegal\_parameter\_look\_through "You can't look through $+1.".

*Other illegal parameter messages*

The above are the default messages and their variations. There are, however, other illegal parameter messages needed at places. They are described below.

The following message is displayed when the player tries to e.g. put something into an actor instance. The verbs in which this message is found are *empty\_in*, *pour\_in*, *put\_in*, and *throw\_in.*:

HAS illegal\_parameter\_act "That doesn't make sense.".

The following message is displayed when the player tries to use the verbs *give*, *put*, *put\_in, put\_on, put\_against*, *put\_near, put\_behind, put\_under, throw\_at, throw\_in, throw\_to*, *use* and *use\_with* with actors as direct objects:

HAS illegal\_parameter\_obj "You can only $v objects.".

The verbs *answer*, *say, say\_to* and *write* require that what we wish to answer, say or write is put into a string ( = surrounded by quotes).

HAS illegal\_parameter\_string "Please state inside double quotes ("""") what you want to $v.".

The verbs *look*\_*behind*, *look\_in* and *look\_under* have the following message when the player tries to look somewhere that is not suitable object for these verbs:

HAS illegal\_parameter\_there "It's not possible to $v there.".

The verb *go\_to* has its own message:

HAS illegal\_parameter\_go “It’s not possible to go there.”

The following is a variation of the above and is used when the second parameter of a ditransitive verb is not suitable.

The verbs *empty\_in, empty\_on, pour\_in, pour\_on, put\_in, put\_on, put\_against, put\_behind, put\_near,*

*put\_under, throw\_in, throw\_to, tie\_to* and *write* use this message:

HAS illegal\_parameter2\_there "It's not possible to $v anything there.".

Finally, there are some messages for the information “verbs” *what\_is*, *where\_is* and *who\_is*. (The first two messages below also apply to *where\_is* besides *what\_is*.)

HAS illegal\_parameter\_what\_sg "That's not something I know about.".

HAS illegal\_parameter\_what\_pl "Those are not something I know about.".

HAS illegal\_parameter\_who\_sg "That's not somebody I know about.".

HAS illegal\_parameter\_who\_pl "Those are not somebody I know about.".

5) Default verb check messages

All these check messages can be individually changed by listing them under the *my\_game* instance in your game source file. They are also listed in the file ‘mygame\_import.i’ in the library distribution package, for easy modification. These check messages are used in verb definitions, mainly in ‘lib\_verbs.i’. Changing one check message will affect all verbs where that particular check is found. Again, as with parameter messages, edit these messages directly in ‘mygame\_import.i’ if you need to change a great number of them, otherwise redefine them within the *my\_game* instance in your own source file. You’ll quickly notice that the list is quite long, and listing any number greater than just a few under the *my\_game* instance would be a rather frustrating task.

a) attribute checks

The general check message for when an instance cannot be used with the verb :

HAS check\_obj\_suitable\_sg "That's not something you can $v.".

HAS check\_obj\_suitable\_pl "Those are not something you can $v.".

Thus, if the player tries to e.g. eat something that is not edible,

>eat book

That’s not something you can eat.

the check message will be displayed.

Note that the illegal parameter messages (above) mostly report cases where the player tried to use a *wrong kind of instance* with a verb:

>take 5

That’s not something you can take.

The verb *take* only works with objects, not with any other instances. Thus, if you try to take something else than an object (for example a numerical value in the above case), an illegal parameter message is shown. This restriction is defined in the syntax of the verb. Checks, on the other hand, are used to ensure that an instance has *the proper* *attribute* needed with the verb, e.g. edible, takeable, NOT open.

Variations of the above message, needed e.g. when a preposition is required after the verb, are listed below:

*fire\_at, throw\_at, throw\_to:*

HAS check\_obj\_suitable\_at “You can’t $v anything at $+2.”

*ask\_for :*

HAS check\_obj2\_suitable\_for\_sg "That's not something you can $v for.".

HAS check\_obj2\_suitable\_for\_pl "Those are not something you can $v for.".

*turn\_off, switch\_off:*

HAS check\_obj\_suitable\_off\_sg "That's not something you can $v off."

HAS check\_obj\_suitable\_off\_pl "Those are not something you can $v off.".

*knock, switch\_on, turn\_on:*

HAS check\_obj\_suitable\_on\_sg "That's not something you can $v on.".

HAS check\_obj\_suitable\_on\_pl "Those are not something you can $v on." .

*play\_with:*

HAS check\_obj\_suitable\_with\_sg "That's not something you can $v with.".

HAS check\_obj\_suitable\_with\_pl "Those are not something you can $v with.".

*break\_with, burn\_with, close\_with, cut\_with, fill\_with, lock\_with, open\_with, pry\_with, push\_with, touch\_with, unlock\_with:*

HAS check\_obj2\_suitable\_with\_sg "That's not something you can $v things with.”.

HAS check\_obj2\_suitable\_with\_pl "Those are not something you can $v things with.".

Again, we have a separate message for *examine, look\_out\_of* and *look\_through*:

HAS check\_obj\_suitable\_examine\_sg "That's not something you can examine.".

HAS check\_obj\_suitable\_examine\_pl "Those are not something you can examine.".

HAS check\_obj\_suitable\_look\_out\_sg "That's not something you can look out of.".

HAS check\_obj\_suitable\_look\_out\_pl "Those are not something you can look out of.".

HAS check\_obj\_suitable\_look\_through "You can't look through $+1.".

*Checks for open, closed and locked objects:*

*open, open\_with:*

HAS check\_obj\_not\_open\_sg "$+1 is already open.".

HAS check\_obj\_not\_open\_pl "$+1 are already open.".

*close, close\_with:*

HAS check\_obj\_open1\_sg "$+1 is already closed.".

HAS check\_obj\_open1\_pl "$+1 are already closed.".

*empty, empty (in/on), look\_in, pour (in/on):*

HAS check\_obj\_open2\_sg "You can't, since $+1 is closed.".

HAS check\_obj\_open2\_pl "You can't, since $+1 are closed.".

*empty\_in, pour\_in, put\_in, throw\_in:*

HAS check\_obj2\_open\_sg "You can't, since $+2 is closed.".

HAS check\_obj2\_open\_pl "You can't, since $+2 are closed.".

*unlock, unlock\_with:*

HAS check\_obj\_locked\_sg "$+1 is already unlocked.".

HAS check\_obj\_locked\_pl "$+1 are already unlocked.".

*lock, lock\_with*:

HAS check\_obj\_not\_locked\_sg "$+1 is already locked.".

HAS check\_obj\_not\_locked\_pl "$+1 are already locked.".

*Checks for "not reachable" and "distant" objects:*

A large number of verbs have the following checks:

HAS check\_obj\_reachable\_sg "$+1 is out of your reach.".

HAS check\_obj\_reachable\_pl "$+1 are out of your reach.".

HAS check\_obj\_not\_distant\_sg "$+1 is too far away.".

HAS check\_obj\_not\_distant\_pl "$+1 are too far away.".

In addition, the verbs *empty\_in,* *fill\_with*, *pour\_in,* *put\_in*, *take\_from* and *tie\_to* have the following check for the reachability of the second parameter:

HAS check\_obj2\_reachable\_sg "$+2 is out of your reach.".

HAS check\_obj2\_reachable\_pl "$+2 are out of your reach.".

and the verb *ask\_for* has the following check:

HAS check\_obj\_reachable\_ask "$+1 wouldn't be able to reach $+2.".

which is triggered when the hero asks an NPC for something that the NPC cannot reach. (This happens when the object in question has the attribute ‘NOT reachable’.)

The verbs *throw\_at, throw\_in, throw\_to* allow the action to succeed if the second parameter is reachable, but not if the second parameter is distant:. Thus, the way things are defined in the library, it is possible to e,g, throw something in a container if that container is otherwise not reachable. But if the container is distant, the action will fail.

HAS check\_obj2\_not\_distant\_sg "$+2 is too far away.".

HAS check\_obj2\_not\_distant\_pl "$+2 are too far away.".

*Checks for the hero sitting or lying\_down:*

Numerous verbs in the library have one of the following checks for sitting:

HAS check\_hero\_not\_sitting1 "It is difficult to $v while sitting down.".

HAS check\_hero\_not\_sitting2 "It is difficult to $v anything while sitting down.".

HAS check\_hero\_not\_sitting3 "It is difficult to $v anywhere while sitting down.".

and for lying down:

HAS check\_hero\_not\_lying\_down1 "It is difficult to $v while lying down.".

HAS check\_hero\_not\_lying\_down2 "It is difficult to $v anything while lying down.".

HAS check\_hero\_not\_lying\_down3 "It is difficult to $v anywhere while lying down.".

If the player uses the verbs *sit* or *sit\_on*, and the hero is already sitting, the following check message is displayed:

HAS check\_hero\_not\_sitting4 "You're sitting down already.".

If the player uses the verbs *lie\_down* or *lie\_in*, and the hero is already lying down, the following check message is displayed:

HAS check\_hero\_not\_lying\_down4 "You're lying down already.".

*Other attribute checks:*

Checking that the object of the action has the ability to talk; verbs *ask, ask\_for, say\_to, tell:*

HAS check\_act\_can\_talk\_sg "That's not something you can talk to.".

HAS check\_act\_can\_talk\_pl "Those are not something you can talk to.".

Checking that the object is allowed to be emptied/poured/put/thrown in the container (*empty\_in, pour\_in, put\_in, throw\_in*):

HAS check\_obj\_allowed\_in\_sg "$+1 doesn’t belong in $+2".

HAS check\_obj\_allowed\_in\_pl “$+1 don’t belong in $+2.”

Checking that something is broken; the verb *fix:*

HAS check\_obj\_broken\_sg "That doesn't need fixing.".

HAS check\_obj\_broken\_pl "Those don't need fixing.".

Checking that the object of the action is inanimate, because normally the action would be considered improper if done to a person: *pull*, *push, push\_with, scratch, search*

HAS check\_obj\_inanimate1 "$+1 wouldn't probably appreciate that.".

With some verbs, the above message is slightly altered; *rub, touch, touch\_with:*

HAS check\_obj\_inanimate2 "You are not sure whether $+1 would appreciate that.".

Checking if something is movable; the verbs *lift, pull, push, push\_with, shake, take, take\_from:*

HAS check\_obj\_movable "It's not possible to $v $+1.".

Checking whether something is scenery; the verbs *examine, take, take\_from:*

HAS check\_obj\_not\_scenery\_sg "$+1 is not important.".

HAS check\_obj\_not\_scenery\_pl “$+1 are not important.”.

In the verbs *ask\_for* and *take\_from* there is also a check for whether the second parameter in the command happens to be a scenery object:

HAS check\_obj2\_not\_scenery\_sg "$+2 is not important.".

HAS check\_obj2\_not\_scenery\_pl “$+2 are not important.”.

For some verbs, the target of looking is checked with the following message: *look\_behind, look\_under:*

HAS check\_obj\_suitable\_there "It's not possible to $v there.".

The verbs *throw\_in* and *tie\_to* has a slightly different formulation from the above:

HAS check\_obj2\_suitable\_there "It's not possible to $v anything there.".

The following check is found in verbs in which implicit taking is possible but the present instance is not takeable:

HAS check\_obj\_takeable "You don't have $+1.".

*fill\_with* has the following check:

HAS check\_obj2\_takeable1 "You don't have $+2.".

while *ask\_for* has:

HAS check\_obj2\_takeable2 "You can't have $+2.".

Checking that an object is not too heavy (*lift, take, take\_from*):

HAS check\_obj\_weight\_sg "$+1 is too heavy to $v.".

HAS check\_obj\_weight\_pl "$+1 are too heavy to $v.".

Checking that an object can be written in/on:

HAS check\_obj\_writeable "Nothing can be written there.".

b) location and containment checks for actors and objects

Location and containment checks for actors other than the hero (checks for the hero are listed separately below):

For the verb *follow* to work successfully, the actor to be followed should be in an adjacent location to the hero. The following check will verify this:

HAS check\_act\_near\_hero "You don't quite know where $+1 went.

You should state direction where you want to go.".

If the hero tries to take something from an NPC and the NPC doesn’t have the stated object, the following check is triggered (*take\_from*):

HAS check\_obj\_in\_act\_sg "$+2 doesn't have $+1.".

HAS check\_obj\_in\_act\_pl "$+2 don't have $+1.".

Similarly, if the player types >give object to actor, and the actor already has that object, the following check message is displayed:

HAS check\_obj\_not\_in\_act\_sg "$+2 already has $+1.".

HAS check\_obj\_not\_in\_act\_pl "$+2 already have $+1.".

*Location and containment checks for the hero*

The following checks deal with where the hero is or what (s)he is carrying.

The verb *shoot* has the following check:

HAS check\_count\_weapon\_in\_hero "You are not carrying any firearms.".

while the following is need for *exit:*

HAS check\_hero\_in\_cont "But you aren't in $+1 at present.".

*enter:*

HAS check\_hero\_not\_in\_cont "But you are already in $+1!".

*find, follow, go\_to, where\_is:*

HAS check\_obj\_not\_at\_hero\_sg "$+1 is right here.".

HAS check\_obj\_not\_at\_hero\_pl "$+1 are right here.".

*drop, fire, fire\_at, put, show:*

HAS check\_obj\_in\_hero "You don't have the $+1.".

The following check is used in many verbs, typically ditransitive ones such as *break\_with*, *cut\_with* etc:

HAS check\_obj2\_in\_hero "You don't have the $+2.".

In the following, the action tried out by the player is targeted at something the hero is holding, and the action would not make sense (verbs *attack, attack\_with, kick,* *lift*, *shoot* and *shoot\_with*):

HAS check\_obj\_not\_in\_hero1 "It doesn't make sense to $v something you're holding.".

The following check ensures that the hero is not trying to get something (s)he already has (the verbs *take, take\_from*):

HAS check\_obj\_not\_in\_hero2 "You already have $+1.".

The throwing verbs (*throw\_at, throw\_in throw\_to*)have this check to prohibit the hero from throwing something at, to or into something that (s)he is holding:

HAS check\_obj2\_not\_in\_hero1 "You are carrying $+2.".

For “putting” verbs other than *put\_in* and *put\_on*, the following check ensures that the player cannot succeed in putting something against, behind, near, on or under something else when (s)he carries the object referenced by second parameter (the verbs *put\_against, put\_behind, put\_near, put\_under*):

HAS check\_obj2\_not\_in\_hero2 "That would be futile.".

Thus, if the player is for example carrying a book, the command

>put apple near book

wouldn’t be successful.

If the hero already is carrying an object that (s)he asks for, the following check message is displayed:

HAS check\_obj2\_not\_in\_hero3 “You already have $+2.”.

*Checking whether an object is in a container or not*

When the following check fires, the player tried to empty the contents of an object into a container that already was contained by the object (e.g. if there is a bottle in a box, and the player types “empty box in bottle”). This applies to the verbs *empty\_in* and *pour\_in*:

HAS check\_cont\_not\_in\_obj "That doesn't make sense.".

If the player tries to take something from a container and that something is not there to begin with, the following check message is displayed (*take\_from*):

HAS check\_obj\_in\_cont\_sg "$+1 is not in $+2.".

HAS check\_obj\_in\_cont\_pl "$+1 are not in $+2.".

If the player tries to put or throw something into a container but the object is already in the container, the following message is displayed *(put\_in, throw\_in):*

HAS check\_obj\_not\_in\_cont\_sg "$+1 is in $+2 already.".

HAS check\_obj\_not\_in\_cont\_pl "$+1 are in $+2 already.".

The following check message is displayed when the player tries to fill a container with something that the container already is full of (*fill\_with*):

HAS check\_obj\_not\_in\_cont2\_sg "$+1 is already full of $+2.".

HAS check\_obj\_not\_in\_cont2\_pl "$+1 is already full of $+2.".

Checking whether an object is on a surface or not (*take\_from*):

HAS check\_obj\_on\_surface\_sg "$+1 is not on $+2.".

HAS check\_obj\_on\_surface\_pl "$+1 are not on $+2.".

Putting something on a surface (*put\_on*):

HAS check\_obj\_not\_on\_surface\_sg "$+1 is already on $+2.".

HAS check\_obj\_not\_on\_surface\_pl "$+1 are already on $+2.".

*Checking whether an object is worn by the hero or not:*

You can’t take off something you’re not wearing *(remove, take\_off)*:

HAS check\_obj\_in\_worn "You are not wearing $+1.".

The following check is for cases when the hero tries to put on something (s)he is already wearing *(put\_on, wear)*:

HAS check\_obj\_not\_in\_worn1 "You are already wearing $+1.".

Here, the action is stopped if the hero tries to attack, kick or shoot something (s)he’s wearing *(attack, attack\_with, kick, shoot, shoot\_with):*

HAS check\_obj\_not\_in\_worn2 "It doesn't make sense to $v something you're wearing.".

Lastly, it’s not possible to drop a piece of clothing if it is worn. It will have to be removed first *(drop)*:

HAS check\_obj\_not\_in\_worn3: “You’ll have to take off $+1 first.”

c) checking location states

The following check is found in numerous verbs. It prohibits actions requiring seeing when the location is not lit:

HAS check\_current\_loc\_lit "It is too dark to see.".

d) logical checks

The checks in this group a) prohibit the action from being directed at the hero, and 2) prohibit the action in ditransitive verbs where both the first and the second parameter refer to the same instance.

*1) prohibiting the action from being directed at the hero:*

The following check is triggered when the player tries something like “attack me”*(ask, ask\_for, attack, attack\_with, catch, follow, kick, listen, pull, push, push\_with, take, take\_from, tell)* :

HAS check\_obj\_not\_hero1 "It doesn't make sense to $v yourself.".

For the verbs *fire\_at, kill, kill\_with, shoot, shoot\_with* there is a specific message when the target of the action is the hero:

HAS check\_obj\_not\_hero2 "There is no need to be that desperate.".

For a couple of actions where the hero is the target, the action might make sense but it is anyway not deemed fruitful. This applies to the verbs *scratch* and *touch*:

HAS check\_obj\_not\_hero3 "That wouldn't accomplish anything.".

The verbs *find* and *go\_to* have the following check triggered when the player types “find me” or “go to me”:

HAS check\_obj\_not\_hero4 "You're right here.".

If the player tries “free me”, the following check message is displayed *(free)*:

HAS check\_obj\_not\_hero5 "You don't have to be freed.".

The verbs *kiss, play\_with* and *rub* have the following check:

HAS check\_obj\_not\_hero6 "There’s no time for that now.".

The verb *look\_behind* has the following check for cases when the hero looks behind him-/herself *:*

HAS check\_obj\_not\_hero7 "Turning your head, you notice nothing unusual behind yourself.".

while *look\_under* has the following one*:*

HAS check\_obj\_not\_hero8 "You notice nothing unusual under yourself.".

Many ditransitive verbs have the following check when the hero tries to perform these actions to her-/himself *(say\_to, show, take\_from, touch\_with, throw\_at, throw\_in, throw\_to)*:

HAS check\_obj2\_not\_hero1 "That doesn't make sense.".

Lastly, some other cases:

*put\_against, put\_behind, put\_near, put\_under:*

HAS check\_obj2\_not\_hero2 "That would be futile.".

*give, tie\_to:*

HAS check\_obj2\_not\_hero3 "You can't $v things to yourself.".

*2) prohibiting the action in ditransitive verbs where both the first and the second parameter refer to the same instance:*

The following checks prohibit actions like “cut rope with rope”, “throw stone at stone” and “put bottle in bottle”:

*fire\_at, throw\_at:*

HAS check\_obj\_not\_obj2\_at "It doesn't make sense to $v something at itself.".

*take\_from:*

HAS check\_obj\_not\_obj2\_from "It doesn't make sense to $v something from itself.".

*empty\_in, pour\_in, put\_in, throw\_in:*

HAS check\_obj\_not\_obj2\_in "It doesn't make sense to $v something into itself.".

*empty\_on, pour\_on, put\_on:*

HAS check\_obj\_not\_obj2\_on "It doesn't make sense to $v something onto itself.".

*give, show, throw\_to, tie\_to:*

HAS check\_obj\_not\_obj2\_to "It doesn't make sense to $v something to itself.".

*attack\_with, break\_with, burn\_with, close\_with, cut\_with, fill\_with , lock\_with, open\_with, pry\_with, push\_with, shoot\_with, touch\_with, unlock\_with, use\_with:*

HAS check\_obj\_not\_obj2\_with "It doesn't make sense to $v something with itself.".

*put\_against, put\_behind, put\_near, put\_under:*

HAS check\_obj\_not\_obj2\_put "That doesn't make sense." .

e) additional checks for classes

Lastly, there are some checks that apply only to a specific class. Most of these are found in ‘lib\_classes.i’.

The first one checks that a male character doesn’t put on women’s clothing by default, and vice versa:

HAS check\_clothing\_sex "On second thoughts you decide $+1 won't really suit you.".

The following check ensures that it won’t be possible to put something inside a supporter object:

HAS check\_cont\_not\_supporter "You can't put $+1 inside $+2.".

If the player tries to turn off a device that is already off, the following check is triggered (*turn\_off, switch\_off*):

HAS check\_device\_on\_sg "$+1 is already off.".

HAS check\_device\_on\_pl "$+1 are already off.".

The following message is triggered if the player tries to turn on a device which is already on (*device: turn\_on, switch\_on*)

HAS check\_device\_not\_on\_sg "$+1 is already on.".

HAS check\_device\_not\_on\_pl "$+1 are already on.".

If the player tries to unlock or lock a door with something that is not the matching key of the door in question (*lock\_with, unlock\_with*):

HAS check\_door\_matching\_key "You can't use $+2 to $v $+1.".

The following message is for situations where the player tries to turn off or extinguish a lightsource that is not lit (*lightsource: extinguish, turn\_off*):

HAS check\_lightsource\_lit\_sg "But $+1 is not lit.".

HAS check\_lightsource\_lit\_pl "But $+1 are not lit.".

while the following is for the opposte case *(lightsource: light, turn\_on)*:

HAS check\_lightsource\_not\_lit\_sg "$+1 is already lit.".

HAS check\_lightsource\_not\_lit\_pl "$+1 are already lit.".

Checking that the verb switch won’t work with a natural lightsource (*lightsource: switch*):

HAS check\_lightsource\_switchable\_sg "That's not something you can switch on and off." .

HAS check\_lightsource\_switchable\_pl "Those are not something you can switch on and off.".

When there is some liquid in a container, e.g. some juice in a bottle, and the player types  *>take juice from bottle*, the following check is triggered (*liquid: take\_from*):

HAS check\_liquid\_vessel\_not\_cont "You can't carry $+1 around in your bare hands.".

When the player tries to turn on a device or light a lightsource which is broken, the following check message is displayed (*device, lightsource: light, turn\_on*):

HAS check\_obj\_not\_broken "Nothing happens.".

6) Implicit taking message

HAS implicit\_taking\_message "(taking $+1 first)$n".

The following verbs use implicit taking:

*bite, drink, eat, empty, empty\_in, empty\_on, give, pour, pour\_in, pour\_on, put\_in, put\_on, throw, throw\_at, throw\_in, throw\_to, tie\_to.*

In ditransitive verbs, only the first parameter (the direct object) is taken implicitly. For example,

>push door with pole

won’t work if the hero is not carrying the pole (= the pole is not taken implicitly).

**Have the game banner show at the start**

To show the game banner at the start, after an optional intro text, you must add the text “DESCRIBE banner.” after the START AT clause:

START AT room1.

DESCRIBE banner.

or:

START AT room1.

“This is the (optional) intro text at the start of the game, before the first location description.”

DESCRIBE banner.

The following attributes should be added to the *my\_game* instance, e.g.:

HAS title "The Baffling Case Of Mrs Wells".

HAS subtitle "An interactive mystery".

HAS author "Sam".

HAS year 2015.

HAS version 1.

Leaving the subtitle line out and setting the version number to “0” will omit these lines from the banner. As it stands now, these attributes would produce the following kind of banner text:

The Baffling Case Of Mrs Wells

An interactive mystery

© 2015 by Sam

Programmed with the ALAN Interactive Fiction Language v3.0

Version 1

All rights reserved

**The philosophy used in deciding successful and unsuccessful outcomes for action in the library verbs**

If you try different actions in-game, with the library imported, you will notice that some actions are successful and result in what the player commanded, while other actions do nothing (= the action is unsuccessful). E.g. the response to > drop [object] will be “Dropped.”, the object being rejected from the hero’s inventory and ending up in the location, while the response to “attack [thing]” is “Resorting to brute force is not the solution here.”. Which actions are allowed to succeed and which are not is based on what is the most reasonable and expected outcome for the action – the outcome that the game author most unlikely needs to edit except for special circumstances. Please experiment with different verbs in-game to see whether the outcome of a particular action is suitable for your game – otherwise redefine the outcome of the verb in the *my\_game* instance.

**Runtime messages**

Many of the runtime messages built into ALAN have been altered in the library from their default wording as stated in the ALAN manual. This is to ensure that plural is handled correctly and that there are no clashes between first and second person. The first person of some default wordings (e.g. “I don’t know the word “$1”) is changed to a more passive or impersonal formulation. To edit these for your game, open ‘lib\_messages.i’ and edit the wanted message(s) there.

MESSAGE

AFTER\_BUT: "You must give at least one object after '$1'."

AGAIN: ""

BUT\_ALL: "You can only use '$1' AFTER '$2'."

CAN\_NOT\_CONTAIN: "$+1 can not contain $+2."

CANT0: "You can't do that."

-- note that the fifth token in CANT0 is a zero, not an 'o'.

CARRIES:

IF parameter1 = hero

THEN "You are carrying"

ELSE

IF parameter1 IS NOT plural

THEN "$+1 carries"

ELSE "$+1 carry"

END IF.

END IF.

CONTAINMENT\_LOOP:

"Putting $+1 in"

IF parameter1 IS NOT plural

THEN "itself"

ELSE "themselves"

END IF.

"is impossible."

CONTAINMENT\_LOOP2:

"Putting $+1 in $+2 is impossible since $+2 already"

IF parameter2 IS NOT plural

THEN "is"

ELSE "are"

END IF.

"inside $+1."

'CONTAINS':

IF parameter1 IS NOT plural

THEN "$+1 contains"

ELSE "$+1 contain"

END IF.

CONTAINS\_COMMA: "$01,"

CONTAINS\_AND: "$01 and"

CONTAINS\_END: "$01."

EMPTY\_HANDED:

IF parameter1 = hero

THEN "You are empty-handed."

ELSE

IF parameter1 IS NOT plural

THEN "$+1 is empty-handed."

ELSE "$+1 are empty-handed."

END IF.

END IF.

HAVE\_SCORED: "You have scored $1 points out of $2."

IMPOSSIBLE\_WITH: "That's impossible with $+1."

IS\_EMPTY:

IF parameter1 IS NOT plural

THEN "$+1 is empty."

ELSE "$+1 are empty."

END IF.

MORE: "<More>"

MULTIPLE: "You can't refer to multiple objects with '$v'."

NO\_SUCH: "You can't see any $1 here."

NO\_WAY: "You can't go that way."

NOT\_MUCH: "That doesn't leave much to $v!"

NOUN: "You must supply a noun."

NOT\_A\_SAVEFILE: "That file does not seem to be an Alan game save

file."

QUIT\_ACTION: "Do you want to RESTART, RESTORE, QUIT or UNDO? "

-- these four alternatives are hardwired to the interpreter and cannot be changed.

REALLY: "Are you sure (press ENTER to confirm)?"

RESTORE\_FROM: "Enter file name to restore from"

SAVE\_FAILED: "Sorry, save failed."

SAVE\_MISSING: "Sorry, could not open the save file."

SAVE\_NAME: "Sorry, the save file did not contain a save for this

adventure."

SAVE\_OVERWRITE: "That file already exists, overwrite (y)?"

SAVE\_VERSION: "Sorry, the save file was created by a different

version."

SAVE\_WHERE: "Enter file name to save in"

SEE\_START:

IF parameter1 IS NOT plural

THEN "There is $01"

ELSE "There are $01"

END IF.

SEE\_COMMA: ", $01"

SEE\_AND: "and $01"

SEE\_END: "here."

NO\_UNDO: "No further undo available."

UNDONE: "'$1' undone."

UNKNOWN\_WORD: "The word '$1' is not understood."

WHAT: "That was not understood."

WHAT\_WORD: "It is not clear what you mean by '$1'."

WHICH\_PRONOUN\_START: "It is not clear if you by '$1'"

WHICH\_PRONOUN\_FIRST: "mean $+1"

WHICH\_START: "It is not clear if you mean $+1"

WHICH\_COMMA: ", $+1"

WHICH\_OR: "or $+1."

**Verb syntaxes used in the standard library**

Verb Synonyms Syntax

about (+ help, info) about

again (+ g) again

answer (+ reply) answer (topic)

ask (+ enquire, inquire, interrogate) ask (act) about (topic)

ask\_for ask (act) for (obj)

attack (+ beat, fight, hit, punch) attack (target)

attack\_with attack (target) with (weapon)

bite bite (obj) break (+ destroy) break (obj)

break\_with break (obj) with (instr)

brief brief

burn burn (obj) burn\_with burn (obj) with (instr)

buy (+ purchase) buy (item) catch catch (obj) clean (+ polish, wipe) clean (obj)

climb climb (obj)

climb\_on climb on (surface) climb\_through climb through (obj)

close (+ shut) close (obj)

close\_with close (obj) with (instr)

consult consult (source) about

(topic)

credits (+ acknowledgments, author, copyright) credits cut cut (obj)

cut\_with cut (obj) with (instr)

dance dance

dig dig (obj)

dive dive

dive\_in dive in (liq)

drink drink (liq)

drive drive (vehicle)

drop (+ discard, dump, reject) drop (obj)

eat eat (food)

empty empty (obj)

empty\_in empty (obj) in (cont)

empty\_on empty (obj) on (surface)

enter enter (cont)

examine (+ check, inspect, observe, x) examine (obj)

exit exit (cont)

extinguish (+ put out, quench) extinguish (obj)

fill fill (cont) fill\_with fill (cont) with (substance) find (+ locate) find (obj)

fire fire (weapon)

fire\_at fire (weapon) at (target

fix (+ mend, repair) fix (obj)

follow follow (act) free (+ release) free (obj)

get\_up get up get\_off get off (obj)

give give (obj) to (recip)

go\_to go to (dest) hint (+ hints) hint

inventory (+ i, inv) inventory

jump jump

jump\_in jump in (cont) jump\_on jump on (surface) kick kick (target) kill (+ murder) kill (victim) kill\_with kill (victim) with (weapon) kiss (+ hug, embrace) kiss (obj)

lie\_down lie down

lie\_in lie in (cont) lie\_on lie on (surface) lift lift (obj)

light (+ lit) light (obj)

listen0 listen

listen listen to (obj)

lock lock (obj)

lock\_with lock (obj) with (key)

look (+ gaze, peek) look look\_at look at (obj)

look\_behind look behind (bulk) look\_in look in (cont) look\_out\_of look out of (obj) look\_through look through (bulk) look\_under look under (bulk) look\_up look up no no notify (on, off) notify.

notify on.

notify off.

open open (obj) open\_with open (obj) with (instr)

play play (obj)

play\_with play with (obj)

pour (= defined at the verb 'empty) pour (obj) pour\_in (= defined at the verb 'empty\_in') pour (obj) in (cont)

pour\_on (= defined at the verb 'empty\_on') pour (obj) on (surface)

pray pray

pry pry (obj)

pry\_ pry (obj) with (instr)

pull pull (obj)

push push (obj)

push\_with push (obj) with (instr)

put (+ lay, place) put (obj)

put\_against put (obj) against (bulk)

put\_behind put (obj) behind (bulk) put\_down put down (obj)

put\_in (+ insert) put (obj) in (cont)

put\_near put (obj) near (bulk)

put\_on put (obj) on (surface)

put\_under put (obj) under (bulk)

read read (obj)

remove remove (obj)

restart restart restore restore rub rub (obj)

save save say say (topic) say\_to say (topic) to (act)

score score scratch scratch (obj)

script script. script on. script

off.

search search (obj)

sell sell (item)

shake shake (obj)

shoot (at) shoot at (target)

shoot\_with shoot (target) with (weapon) shout (+ scream, yell) shout

show (+ reveal) show (obj) to (act)

sing sing sip sip (liq)

sit (down) sit. sit down.

sit\_on sit on (surface)

sleep (+ rest) sleep

smell0 smell

smell smell (odour) squeeze squeeze (obj)

stand (up) stand. stand up.

stand\_on stand on (surface)

swim swim swim\_in swim in (liq)

switch\_on (defined at the verb 'turn\_on') switch on (app)

switch\_off (defined at the verb 'turn\_off’) switch off (app)

take (+ carry, get, grab, hold, obtain) take (obj)

take\_from (+ remove from) take (obj) from (holder)

talk talk talk\_to (+ speak) talk to (act)

taste (+ lick) taste (obj)

tear (+ rip) tear (obj)

tell (+ enlighten, inform) tell (act) about (topic)

think think

think\_about think about (topic)

throw throw (projectile)

throw\_at throw (projectile) at (target)

throw\_in throw (projectile) in (cont)

throw\_to throw (projectile) to (recipient)

tie tie (obj)

tie\_to tie (obj) to (target)

touch (+ feel) touch (obj) turn (+ rotate) turn (obj)

turn\_on turn on (app)

turn\_off turn off (app) undress undress

unlock unlock (obj)

unlock\_with unlock (obj) with (key)

use use (obj)

use\_with use (obj) with (instr)

verbose verbose

wait (+ z) wait

wear wear (obj)

what\_am\_i what am i

what\_is what is (obj) where\_am\_i where am i

where\_is where is (obj)

who\_am\_i who am i

who\_is who is (obj)

write write (txt) on (obj)

yes yes

To see the outcome for all verbs above, check the file ‘mygame\_import.i’ where you’ll find a list of all verb outcomes. The syntaxes of these verbs are defined in the library file ‘lib\_verbs.i’.

Note that the ‘exit’ and ‘enter’ verbs won’t have successful outcomes by default; after all, it is impossible to place an actor (like the hero) inside a container in the current version of ALAN. To make for example the command >*enter car* work, you should make the car a separate location and then locate the hero there at the DOES ONLY part of the ‘enter’ verb in the car instance. In other words, simulate entering and exiting by locating the hero in between locations.

**Default attributes for things used in the standard library**

These attributes are added to every ‘thing’ instance in the library:

IS examinable.

inanimate.

movable.

open.

reachable.

-- See also 'distant' below

takeable.

HAS allowed {null\_object}.

-- you can only put an object in a container if the object

-- is in the ‘allowed’ set of the container.

HAS matching\_key null\_key.

-- All lockable objects need a matching key to lock/unlock them.

-- "null\_key" is a default dummy that can be ignored.

HAS text "".

NOT broken.

NOT distant.

-- Usage: you can e.g. talk to a "not reachable" actor but not to

-- a "distant" one.

-- You can also throw things in, to or at a not reachable target

-- but not to a distant one.

-- The other verbs where the action succeeds if the object is

-- not reachable are: dive\_in, fire\_at, kill\_with, read, and

-- shoot

-- Default response for not reachable things: "The [thing] is out

-- of your reach."

-- Default response for distant things: "The [thing] is too far

-- away."

NOT drinkable.

NOT edible.

NOT fireable.

-- can (not) be used as a firearm

NOT lockable.

NOT locked.

NOT openable.

NOT readable.

NOT scenery.

-- has special responses for ‘ask\_for’, 'examine','take' and

-- ‘take\_from’, behaves like a

-- normal object otherwise.

NOT wearable.

NOT writeable.

CAN NOT talk.

**Translating to other languages**

To translate the ALAN system and library to other languages, you should

1) translate all the messages in the file ‘lib\_definitions.i’:

- the two messages for the hero

- the two messages for dark locations

- all illegal parameter messages

- all verb check messages

- the message for implicit taking

- the message lines for the banner instance where applicable

2) translate the verb syntaxes in ‘lib\_verbs.i’ (not parameters and the ELSE parts).

For example for the verb ‘attack’ when translated into French:

SYNTAX attaquer = attaquer (target)

WHERE target ISA THING

ELSE

IF target IS NOT plural

THEN SAY illegal\_parameter\_sg OF my\_game.

ELSE SAY illegal\_parameter\_pl OF my\_game.

END IF.

Also, translate the verb names, e.g. VERB attack DOES … becomes, translating into French, VERB attaquer DOES … etc.), and the verb outcomes (what happens after DOES).

3) translate the verb outcomes for class objects (what happens after DOES or DOES ONLY) in ‘lib\_classes.i’.

4) translate the direction names, their synonyms and the few marginal verb outcomes for indoor and outdoor objects in ‘lib\_locations.i’

5) translate the runtime messages in ‘lib\_messages.i’.

Now, every possible response and message in the game is shown in the target language, and it is possible for the player to issue commands in the target language.

**Reference guide**

This reference guide will deal with subjects some of which are already handled previously in this manual, while other subjects are dealt with here for the first time.

**I want to…**

**… override the library response to a verb**

Define the verb outcome with a DOES ONLY section within the *my\_game* instance:

THE my\_game ISA DEFINITION\_BLOCK

VERB examine

DOES ONLY “Nothing special really.”

END VERB.

END THE.

**… override the library response to a verb within a specific class:**

EVERY cat ISA ACTOR

VERB examine

DOES ONLY “It’s just an ordinary cat.”

END VERB.

END EVERY.

This will override the default library message for *examine* for all cats in the game.

If you want to change the verb outcome for a class predefined in the library, do like below. Here, the verb

outcome for *examine* has been modified for all windows in the game:

THE my\_game ISA DEFINITION\_BLOCK

VERB examine

DOES ONLY

IF obj ISA WINDOW

THEN “Better not be looking out of windows.”

-- this applies for all windows

ELSE “Nothing special really.”

-- this applies for all other obejcts

END IF.

END VERB.

END THE.

**… override the library response to a verb within a specific instance only**

Use DOES ONLY at the instance:

THE little\_cat ISA ACTOR AT garden

VERB examine

DOES ONLY “It’s a little black and white cat with yellow

eyes.”

END VERB.

END THE.

**… to add a check to a library verb**

Add the check to the verb under the *my\_game* instance and *not* in the library file:

THE my\_game ISA DEFINITION\_BLOCK

VERB take

CHECK COUNT ISA ACTOR, AT hero = 1

-- ( = only the hero, and nobody else, is present)

ELSE “Remember that in this game you are a thief.

You shouldn’t take anything while there is

somebody else in the same location.”

END VERB.

END THE.

Note that there is no DOES ONLY part above. (The hero will be counted as one actor “AT hero”. That’s

why above, the count check is formulated the way it is.)

**… to add a check to a verb for a specific class**

ADD TO EVERY cat

IS takeable.

VERB take

CHECK nails OF THIS ARE cut

ELSE “You might just get scratched.”

END VERB.

END ADD.

Note that there is no DOES/DOES ONLY section here; the check is performed on the cat class

only, and if the check is passed, the library outcome of the *take* verb will be carried out.

**… to add a check to a verb for a specific instance**

Add the check to the instance (and not to the library nor to the *my\_game* instance):

THE soup ISA OBJECT AT kitchen

IS edible.

IS NOT hot.

VERB eat

CHECK soup IS hot

ELSE “You must warm the soup first.”

END VERB.

END THE soup.

Note that there is no DOES/DOES ONLY section here; the check is performed on the soup instance

only, and if the check is passed, the library outcome of the *eat* verb will be carried out.

**… to change the syntax of a library verb**

a) without accessing the library:

Let’s say that you want to for example change the syntax of the *talk\_to* verb. Elsewhere in this manual

you’ll find all verb syntaxes listed. From there, you’ll find out that the syntax of the *talk* verb is

talk\_to = talk ‘to’ (act).

Let’s imagine that you want to change this so that it’s possible for the player to type

>talk man

or just

>t man

i.e. stating the character with whom you wish to talk, after the verb, without the preposition ‘to’.

The easiest way to allow this is just to add an additional syntax for ‘talk\_to’ in your own game file:

SYNTAX talk\_to = talk (act).

talk\_to = t (act).

This syntax declaration should be *outside* the *my\_game* instance, in your game file. This syntax

declaration won’t cancel the original syntax for ‘talk\_to’ defined in the library; it would still be

possible for the player to type >talk to man, as well.

If you wish to cancel the original syntax altogether, do like this in your own game file:

THE my\_game ISA DEFINITION BLOCK

VERB talk\_to

DOES ONLY “To talk to someone, type ““talk [person]”” or just

““t [person]””.”

END VERB.

END THE my\_game.

Then, outside the *my\_game* instance, define your own *talk* verb, e.g.:

SYNTAX my\_talk\_to = talk (act)

WHERE act ISA ACTOR

ELSE …

VERB my\_talk\_to

DOES

IF act = mr\_smith

THEN…

ELSIF…

END VERB.

SYNONYMS t = talk.

b) accessing the library:

Find the verb in the library file ‘lib\_verbs.i’ and make the desired changes to the syntax. (If you add or

change a parameter, make sure that the verb checks function properly.)

**… to change the pre-defined illegal parameter messages in syntax statements**

Please refer to a previous section in this manual where all illegal parameter messages are listed.

To change some of them, re-declare them within the *my\_game* instance:

THE my\_game ISA DEFINITION\_BLOCK

HAS illegal\_parameter\_sg “You can’t $v $+1.”

HAS illegal\_parameter\_pl “You can’t $v $+1.”

HAS illegal\_parameter\_there “You can’t $v there.”

END THE.

If you need to change a great number, or all, of the parameter messages (for example to adjust the messages for an unusual narrative perspective, or if you’re writing in a language other than English), it’s better to open ‘mygame\_instance.i’ and find the list of illegal parameter messages, and do all the changes straight there. This will save you a lot of typing. Remember to import the ’mygame\_instance.i’ file to your game.

**… to change the pre-defined illegal parameter message of a single verb**

The way the illegal parameter messages have been defined in the library, it is not usually possible to affect just one verb at a time. Most often, changing a default message will alter the outcome of at least a handful of verbs, because one default message is shared by many verbs. There are some default parameter messages that only affect one verb; you should check the list of parameter messages (above) for details. Anyway, the quickest way to accomplish this task would be to open ‘lib\_verbs.i’, find the verb, then modify the appropriate parameter message in its syntax statement.

**… to change the wording of a library-defined verb check**

Find the check in the list of check messages in this manual, or in ‘mygame\_import.i’. Re-declare it in within the *my\_game* instance. Here we change the wording for *check\_obj\_writeable* which in its default form is “Nothing can be written there.”:

THE my\_game ISA DEFINITION\_BLOCK

HAS check\_obj\_writeable “You can’t write anything on $2.”

END THE.

**… to remove a check from a verb**

This requires accessing the library. Go to ‘lib\_verbs.i’, find the verb you wish to remove a check from and

remove the check. (Make sure the behavior of things in your game remains sensible; the library verb

checks, after all, are there to ensure that everything functions in a reasonable and rational way.)

**… to change the attribute of a class:**

a) giving a predefined attribute to a class of your own:

EVERY broken\_vase ISA OBJECT

IS broken.

END EVERY.

Objects are by default NOT broken. If we want a class of objects that all share the same attribute, like

“broken”, we can override the default this way.

b) changing the predefined attribute of a class defined in the library.

Use INITIALIZE in the *my\_game* instance. Here, the game author wants (for some reason) to make

all CLOTHING objects not wearable:

THE my\_game ISA DEFINITION\_BLOCK

INITIALIZE

FOR EACH c ISA CLOTHING DO

MAKE c NOT wearable.

END FOR.

END THE my\_game.

**… make a new verb for your game**

Declare a new verb in the normal manner in your own game source file, outside any instances:

SYNTAX test = test.

VERB test

DOES “Test successful.”

END VERB.

or

SYNTAX test = test (obj)

WHERE obj ISA OBJECT

ELSE “That’s not something you can test.”

ADD TO EVERY OBJECT

VERB test

DOES “You test” SAY THE obj. “successfully.”

END VERB.

END ADD.

**… make a verb apply to one instance only (e.g. > cross the street, with *cross* meant to be working**

**with the street instance only:**

Place the verb within the needed instance:

THE street ISA OBJECT AT town

VERB cross

DOES “There’s too much traffic.”

END VERB.

END THE.

This way, the verb only applies to the street instance. Its syntax won’t need to be defined anywhere else. If the player tries to use it somewhere else, e.g. >cross table, the outcome will be “You can’t do that.” (the default outcome for the MESSAGE CANT0), unless the player defines an individual outcome for the verb under another instance where a successful outcome for the verb is wished:

THE brook ISA OBJECT AT forest

VERB cross

DOES “You would just get your feet wet.”

END VERB.

END THE.

**… add a synonym for an existing verb**

Declare the synonym in your own game source file, outside any instance declarations, and outside the *my\_game* instance, like this:

SYNONYMS peruse = read.

… **override automatic implicit taking**

Locate the verb(s) for which you want to override implicit taking in ‘lib\_verbs.i’ or in ‘mygame\_import.i’, find their DOES ONLY sections and delete the implicit taking code.

**… edit default runtime messages**

This is not possible without accessing the library. Please open the file ‘lib\_messages.i’ in the library files and edit the wanted messages there.

**Short examples**

1) A very short complete game using minimal obligatory imports and coding. Here, the hero must go from room1 north to room2 and eat an apple to win the game.

IMPORT ‘library.i’.

THE my\_game ISA DEFINITION\_BLOCK  
END THE.

THE room1 ISA LOCATION

DESCRIPTION “North to room2.”

EXIT north TO room2.  
END THE.

THE room2 ISA LOCATION

DESCRIPTION “South to room1.”

EXIT south TO room1.

END THE.

THE apple ISA OBJECT AT room2

IS edible.

VERB eat

DOES “Congratulations!” QUIT.

END VERB.

END THE.

START AT room1.

DESCRIBE banner.

(This game wouldn’t actually need the library at all; it would be even shorter to code:)

THE room1 ISA LOCATION

DESCRIPTION “North to room2.”

EXIT north TO room2.

END THE.

THE room2 ISA LOCATION

DESCRIPTION “South to room1.”

EXIT south TO room1.

END THE.

THE apple ISA OBJECT AT room2

VERB eat

DOES “Congratulations!” QUIT.

END VERB.

END THE.

START AT room1.

In this latter case, though, the player wouldn’t e.g. be able to examine him-/herself, take inventory, try various things with the apple, quit properly, etc.

Examples 2-4 below show mainly different variations of the *my\_game* instance and not complete games:

2) In this example of defining the *my\_game* instance, the author has changed the default verb responses for ‘eat’, ‘climb’ and ‘take\_from’. In addition, the author has added a check and a response of his/her own to ‘take\_from’:

THE my\_game ISA DEFINITION\_BLOCK

VERB eat

DOES ONLY “You don’t feel like eating anything in this game.”

END VERB.

VERB climb

DOES ONLY “Let’s just stay on the ground, shall we?”

END VERB.

VERB take\_from

WHEN obj

CHECK COUNT ISA ACTOR, AT hero = 1 -- ( = the hero himself)

ELSE “You don’t want to take anything while somebody

might be looking.”

DOES “Triumphantly, you fish” SAY THE obj. “out of”

SAY THE holder. “.”

END VERB.

END THE.

3) Here, the author uses the automatic formulation for the game title, author, and other information:

THE my\_game ISA DEFINITION\_BLOCK

HAS title "The Lost Treasure".

HAS subtitle "An interactive treasure hunt".

HAS author "Sam".

HAS year 2015.

HAS version 1.

END THE.

THE garden ISA LOCATION

DESCRIPTION “…”

END THE.

START AT garden.

DESCRIBE banner.

4) Here, the game author has added a check of his own to the library-defined ‘drink’ verb and changed an illegal parameter message for the verbs *look\_behind*, *look\_in*, and *look\_under*:

THE my\_game ISA DEFINITION\_BLOCK

VERB drink

CHECK hero IS thirsty

ELSE “You don’t feel like drinking anything right now.”

END VERB.

HAS illegal\_parameter\_there “You can’t $v there.".

END THE.

5) A complete example game with locked doors and keys. This code reintroduces the situation used in example 1, with a locked door and two keys added.

IMPORT 'lib\_classes.i'.

IMPORT 'lib\_definitions.i'.

IMPORT 'lib\_locations.i'.

IMPORT 'lib\_messages.i'.

IMPORT 'lib\_verbs.i'.

THE my\_game ISA DEFINITION\_BLOCK

END THE.

THE room1 ISA LOCATION

DESCRIPTION "North to room2."

EXIT north TO room2

CHECK locked\_door\_1 IS open

ELSE "The door to the north is on the way."

END EXIT.

END THE.

THE locked\_door\_1 ISA DOOR AT room1

DESCRIPTION ""

NAME door

HAS otherside locked\_door\_2.

IS lockable. IS locked.

HAS matching\_key silver\_key.

END THE.

THE silver\_key ISA OBJECT AT room1

NAME silver key

END THE.

THE brass\_key ISA OBJECT AT room1

NAME brass key

END THE.

THE room2 ISA LOCATION

DESCRIPTION "South to room1."

EXIT south TO room1

CHECK locked\_door\_2 IS open

ELSE "The door to the south is on the way."

END EXIT.

END THE.

THE locked\_door\_2 ISA DOOR AT room2

DESCRIPTION ""

NAME door

END THE.

THE apple ISA OBJECT AT room2

IS edible.

VERB eat

DOES "Congratulations!" QUIT.

END VERB.

END THE.

START AT room1.

DESCRIBE banner.